How Many Bugs in a Box/How Many Bugs in a Box.cdr/bugs/act5/00385_run time tools.ls

Text File | 1995-03-28 | 3.3 KB | 118 lines

on mydelay putz
  set ptime to the timer + putz
  repeat while the timer < ptime
    if the mouseDown then
      exit repeat
    end if
  end repeat
end

on smovespecial sold, stime, param
  global stinktime
  set sx to the locH of sprite sold
  set stime to the timer + (stime * 1.0)
  set ptimer to the timer
  set dx to getAt(param, 1)
  set xinc to (dx - sx) / (stime - ptimer)
  repeat while the timer < stime
    set ptime to the timer - ptimer
    set the locH of sprite sold to sx + (xinc * ptime)
    updateStage()
    if the timer < stinktime then
      set the castNum of sprite 26 to the number of cast ("hed" & random(3))
    end if
  end repeat
  set the locH of sprite sold to dx
  updateStage()
end

on smove sold, stime, param
  set sx to the locH of sprite sold
  set sy to the locV of sprite sold
  set stime to stime * 1.0
  set dx to getAt(param, 1)
  set dy to getAt(param, 2)
  set xinc to (dx - sx) / stime
  set yinc to (dy - sy) / stime
  startTimer()
  repeat while the timer < stime
    set ptime to the timer
    set the locH of sprite sold to sx + (xinc * ptime)
    set the locV of sprite sold to sy + (yinc * ptime)
    set the castNum of sprite 26 to the number of cast ("hed" & random(3))
    updateStage()
  end repeat
  set the locH of sprite sold to dx
  set the locV of sprite sold to dy
  updateStage()
end

on smovenoanim sold, stime, param
  set sx to the locH of sprite sold
  set sy to the locV of sprite sold
  set stime to stime * 1.0
  set dx to getAt(param, 1)
  set dy to getAt(param, 2)
  set xinc to (dx - sx) / stime
  set yinc to (dy - sy) / stime
  set rubtime to the timer
  repeat while the timer < (stime + rubtime)
    set ptime to the timer - rubtime
    set the locH of sprite sold to sx + (xinc * ptime)
    set the locV of sprite sold to sy + (yinc * ptime)
    updateStage()
  end repeat
  set the locH of sprite sold to dx
  set the locV of sprite sold to dy
  updateStage()
end

on sdeact params
  if not listp(params) then
    set the locV of sprite params to -(the locV of sprite params)
    puppetSprite(params, 1)
  else
    set num to count(params)
    repeat with xxx = 1 to num
      set snum to getAt(params, xxx)
      set the locV of sprite snum to -(the locV of sprite snum)
      puppetSprite(snum, 0)
    end repeat
    updateStage()
  end if
end

on sactivate sold, params
  puppetSprite(sold, 1)
  if listp(params) then
    set the locH of sprite sold to getAt(params, 1)
    set the locV of sprite sold to getAt(params, 2)
    set the type of sprite sold to getAt(params, 3)
    set the castNum of sprite sold to getAt(params, 4)
    set the ink of sprite sold to getAt(params, 5)
    set the foreColor of sprite sold to getAt(params, 6)
    set the backColor of sprite sold to getAt(params, 7)
    set the visible of sprite sold to getAt(params, 8)
  end if
end

on ssetpos sold, params
  set the locH of sprite sold to getAt(params, 1)
  set the locV of sprite sold to getAt(params, 2)
end

on sinfo sold
  set stemp to list(the locH of sprite sold, the locV of sprite sold, the type of sprite sold)
  add(stemp, the castNum of sprite sold)
  add(stemp, the ink of sprite sold)
  add(stemp, the foreColor of sprite sold)
  add(stemp, the backColor of sprite sold)
  add(stemp, the visible of sprite sold)
  return stemp
end

on sgetpos sold
  set stemp to list(the locH of sprite sold, the locV of sprite sold)
  return stemp
end